* MAX4004 MACROMODEL
* ------------------------------
* Revision 0, 8/2004
* ------------------------------
* The MAX4004 is a precision, high-side, high-voltage current monitor which 
* outputs a current proportional to the reference current and feature over
* current protection, thermal protection and output voltage clamp option. 
* * ------------------------------
* Connections
*          1  = CLAMP
*          2  = GND
*          3  = OUT
*          4  = REF 
*          6  = BIAS 
*$
***************************************
***************************************
.SUBCKT MAX4004 1 2 3 4 6
 XAMP 1 2 3 4 6 MAX4004_S
.ENDS
***************************************
.SUBCKT MAX4004_S 16 18 30 17 10  
* 10 = BIAS
* 18 = GND
* 17 = REF
* 16 = CLAMP
* 30 = OUT
*****************
RL1 10 21 241
VL1 21 27 0.2
IL1 22 A17 20M
DL2 A17 22 DA
IL2 A17 18 20P
VL2 23 27 0.8
DL1 23 10 DA
VS 27 22 0V
DIN A17 17 DA
IBIAS 10 18 31.51U
RBIAS 10 18 0.607MEG
GPSRR 10 30 POLY(2) 25 18 10 18 0 0 0 0 50U
FP 18 25 VS 0.1M
RP 18 25 1K
CP 25 18 50P
GOUT 10 30 25 18 1
DL3 30 24 DA
VL3 10 24 0.85
DL4 30 16 DB
ICL 16 18 1P
FIMP 18 26 VS 1M
RIMP 26 18 1K
GIMP 30 18 POLY(2) 30 18 26 18 0 0 0 0 80U  
**********************************************************
.MODEL DA D(N=0.1M)
.MODEL DB D(IS=100E-14)
**********************************************************
.ENDS
*$