* MAX965 MACROMODEL
* ------------------------------
* Revision 0, 9/2005
* ------------------------------
* Model Platform: Pspice
* ------------------------------
* The MAX965 comparator feature rail to rail input and outputs, and fully
* specified single-supply operation down to +1.6V. This device offers  
* programmable hysterisis, an internal 1.235 reference and open-drain output 
* which can be pulled beyond VCC to 6V above ground.
* ------------------------------
* Note1: Reference sink current, and input bias currents are not modeled
* ------------------------------
* Connections
*          1  = GND
*          2  = NC
*          3  = IN+
*          4  = IN-
*          5  = HYST
*          6  = REF
*          7  = VCC
*          8  = OUT
*******************************
.SUBCKT MAX965 1 3 4 5 6 7 8
*******************************
VG1 G1 1 0V
VRG1 V1 G1 1V
VRG2 V5 G1 0.5V
VRG3 V2 G1 2V
*******************************
*INPUT STAGE
IGBIAS 7 IN1 2U
MIN1 IN2 IN4 IN1 CM2 MOSP L=5U W=10U
MIN2 IN3 4 IN1 CM2 MOSP L=5U W=10U
RIN1 IN2 G1 10K
RIN2 IN3 G1 10K
EPSR IN4 IN5 VALUE={V(7,G1)*0.1M}
ECMR IN7 IN5 VALUE={V(IN1,6)*1.5M}	
VOS IN7 IN8 3M
EHYST IN8 3 H1 G1 1
CIN1 IN4 G1 7P
CIN2 4 G1 7P
********
VIL CM1 G1 600M
EIL CM2 G1 VALUE={V(7,G1)+0.75}
DIL1 CM1 IN1 DA
DIL2 IN1 CM2 DA
*****************
*GAIN STAGE
GA1 G1 A1 IN3 IN2 1
CA3 A1 G1 100N
DA2 G1 A1 DA
DA1 A1 V1 DA
CA1 G1 A1 10P
EA1 A2 G1 A1 G1 1
RA2 A2 A3 1K
CA2 A3 G1 10N
XBUF1 A3 A4 G1 BUFF
*****************
*REFERENCE
RRF1 6 G1 958
IRF1 G1 6 1.2891M
DRF1 6 RF1 DY
EVC RF1 G1 7 G1 686M
*****************
*HYST
EH1 H1 G1 VALUE={V(A1,V5)*(V(H2,G1)*2+2M)}
GH1 G1 H2 6 5 1M
RH1 H2 G1 1K
DH1 G1 H2 DA
VH1 H3 G1 49M
DH2 H2 H3 DA
RH2 5 G1 123MEG
*****************
*OUTPUT
MOUT 8 O1 G1 G1 MOSN L=5U W=21.8U
EO1 O1 G1 VALUE={V(V1,A4)*V(7,G1)}
ILEAK 8 G1 1N
*****************
*SUPPLY CURRENTS
ISUP 7 G1 5U
**********************************************************
.MODEL MOSN NMOS(VTO=0.7 KP=16E-5)
.MODEL MOSP PMOS(VTO=-0.7 KP=88E-5)
.MODEL DA D(N=0.1M)
.MODEL DY D(N=10M)
**********************************************************
.ENDS
****************************
.SUBCKT BUFF IN OUT G1
VRG1 V1 G1 1V
VRG2 V5 G1 0.5V
GBU1 G1 BU1 VALUE={V(IN,V5)+(V(BU1,G1)*10M)} 
DBU1 BU1 V1 DA
DBU2 G1 BU1 DA
CBU1 BU1 G1 0.1P
EOUT OUT G1 BU1 G1 1
RBU1 BU1 G1 1MEG
.MODEL DA D(N=0.1M)
.ENDS
****************************